如何根据值确定节点的位置-xml-IT问答社区-解决你的IT疑问

如何根据值确定节点的位置

Devops-Paddy 1月前

我正在尝试根据节点的值获取其位置，以便我可以获取相应的条目。这是源 XML： ...

我正在尝试根据节点的值获取其位置，以便可以获得相应的条目。

以下是源 XML：

<?xml version="1.0" encoding="UTF-8"?>
<sampleSourceXML>
    <Table>
        <Header>
            <Column>Name</Column>
            <Column>Surname</Column>
            <Column>Title</Column>
        </Header>
        <Body>
            <Row>
                <Entry>James</Entry>
                <Entry>Bond</Entry>
                <Entry>Mr</Entry>
            </Row>
            <Row>
                <Entry>Harry</Entry>
                <Entry>Potter</Entry>
                <Entry>Mr</Entry>
            </Row>
        </Body>
    </Table>
</sampleSourceXML>

这是我想要实现的 XML 结果：

<?xml version="1.0" encoding="UTF-8"?>
<sampleResultXML>
    <Person>
        <FirstName>James</FirstName>
        <LastName>Bond</LastName>
        <Title>Mr</Title>
    </Person>
    <Person>
        <FirstName>Harry</FirstName>
        <LastName>Potter</LastName>
        <Title>Mr</Title>
    </Person>
</sampleResultXML>

我尝试用这个 XSLT：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes"/>
    <xsl:strip-space elements="*"/>
    
    <xsl:template match="/">
        <xsl:element name="sampleResultXML">
            <xsl:for-each select="sampleSourceXML/Table/Rows/Row">
                <xsl:element name="Person">
                    <xsl:element name="FirstName">
                        <xsl:value-of select="./Entry[1]/text()"></xsl:value-of>
                    </xsl:element>
                    <xsl:element name="LastName">
                        <xsl:value-of select="./Entry[2]/text()"></xsl:value-of>
                    </xsl:element>
                    <xsl:element name="Title">
                        <xsl:value-of select="./Entry[3]/text()"></xsl:value-of>
                    </xsl:element>
                </xsl:element>
            </xsl:for-each>
        </xsl:element>
    </xsl:template>
</xsl:stylesheet>

这有效。

但源 XML 可以有不同的顺序。例如，Title 元素可以位于 Name 元素上方。因此，我的 XSLT 中的硬编码位置（例如 Entry[3]）将不再起作用。

标题顺序和条目顺序始终是对应的。因此，如果列标题位于位置 3，则相应的行也将位于位置 3。

因此，我需要一种方法来动态获取 Title 元素的位置。因此，我必须遍历 Column 元素，直到找到值为 \'Title\' 的元素。我想将此位置保存在一个变量中（例如 Position_Title），以便稍后可以像这样填充该值：

<xsl:element name="Title">
  <xsl:value-of select="./Entry[$Position_Title]/text()"></xsl:value-of>
</xsl:element>

但是我还没能找到方法来做到这一点。

您知道我该如何实现这一目标吗？

帖子版权声明 1、本帖标题：如何根据值确定节点的位置
本站网址：http://xjnalaquan.com/
2、本网站的资源部分来源于网络，如有侵权，请联系站长进行删除处理。
3、会员发帖仅代表会员个人观点，并不代表本站赞同其观点和对其真实性负责。
4、本站一律禁止以任何方式发布或转载任何违法的相关信息，访客发现请向站长举报
5、站长邮箱：yeweds@126.com 除非注明，本帖由Devops-Paddy在本站《xml》版块原创发布，转载请注明出处！

最新回复 (0)

最新倒序只看楼主

147875 1月前 0 只看Ta

引用 2楼
因此，我需要一种方法来动态获取 Title 元素的位置。因此，我必须遍历 Column 元素，直到找到值为 \'Title\' 的元素。我想将此位置保存在一个变量中（例如 Position_Title），以便稍后可以像这样填充该值：

我认为如果你从相反的方向做的话会简单得多。尝试：

XSLT 1.0
```
<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>

<xsl:template match="/sampleSourceXML">
    <xsl:variable name="cols" select="Table/Header/Column" />
    <sampleResultXML>
        <xsl:for-each select="Table/Body/Row">
            <Person>
                <xsl:for-each select="Entry">
                    <xsl:variable name="i" select="position()" />
                    <xsl:element name="{$cols[$i]}">
                        <xsl:value-of select="."/>
                    </xsl:element>
                </xsl:for-each> 
            </Person>
        </xsl:for-each> 
    </sampleResultXML>
</xsl:template>

</xsl:stylesheet>
```
Doug Knudsen 1月前 0 只看Ta

引用 3楼

谢谢！这太有帮助了！我做了一点调整，这样我就可以设置我自己的名字了，但如果没有你，我不知道这要花多长时间！
Prabhat Mangina 1月前 0 只看Ta

引用 4楼

我会寻找一种方法来用您想要的名称替换原始名称，然后将结果存储在 $cols 变量中。